Hi!

I created a composite control that inherits from the WebControls.Button. I added the following in the Load event:

        Dim mHidden As New WebControls.HiddenField
        Me.Controls.Add(mHidden)

but the control is not created. Why?

---

Dimitris Papadimitriou

Hi,

Child controls on Button do not make much sense (how would you expect them to be rendered, doesn't button allow only text into value attribute?). 

Button allows child controls to be added, but they won't be rendered because Button's Render(), inherited from WebControl, calls RenderBeginTag(), RenderContents() and RenderEndTag(). RenderContents() is overridden so that it does nothing.

Button renders as <input type=button> and it is not required to have even closing tag (with ASP.NET 2.0 and XHTML case if of course different)

---

Thanks,

Teemu Keiski
Finland, EU

I AM using ASP.NET 2. Forgot to mention.
So... how can I make my control to add an extra control apart from the one being inherited?

---

Dimitris Papadimitriou

Makes no difference to the functionality. It's the same with v2, just that there's adapters yet involved however the calls go the same route.

Can you describe why do you need to inherit a Button while adding also child controls? Couldn't you inherit from a WebControl (create a pure composite one), where you'd use Button as one child control?

---

Thanks,

Teemu Keiski
Finland, EU

The reason is that I want my new control to inherit all the buttons functionality, since it will mainly be a button. I just want it to do some things using javascript and return the result in the hidden field, so that it is posted back to the server.

---

Dimitris Papadimitriou

Ok,

I see. You can inherit from Button but it needs a bit different approach. Hhere's basic skeleton for you. It has a Button which registers a hidden field using Page.ClientScript.RegisterHiddenField and demonstrates how to keep up the hidden field value within postbacks in this case. It also exposes the hidden field value out as a property.

You need to add yourself the client-script related stuff as well as otherwise maybe modify it.

Imports Microsoft.VisualBasic
Imports System.Web
Imports System.Web.UI
Imports System.Web.UI.WebControls

Public Class MyButton
    Inherits Button
    Implements IPostBackDataHandler

    Protected Overrides Sub OnPreRender(ByVal e As System.EventArgs)
        MyBase.OnPreRender(e)
        'Registering the hidden field for every request
        If Not Me.Page Is Nothing Then
            Page.ClientScript.RegisterHiddenField(HiddenClientID, HiddenValue)
        End If
    End Sub

    'Property to keep hidden field value in View state of the control
    Public Property HiddenValue() As String
        Get
            Return CStr(ViewState("HiddenValue"))
        End Get
        Set(ByVal value As String)
            ViewState("HiddenValue") = value
        End Set
    End Property

    'ID which is used to register the hidden field as well as read its value
    Protected ReadOnly Property HiddenClientID() As String
        Get
            Return Me.ClientID & "_hidden"
        End Get
    End Property

    'Participating to the postback processing so that we can take the posted hidden field value
    Public Function LoadPostData(ByVal postDataKey As String, ByVal postCollection As System.Collections.Specialized.NameValueCollection) As Boolean Implements System.Web.UI.IPostBackDataHandler.LoadPostData
        Dim value As String = postCollection(HiddenClientID)
        HiddenValue = value

        'Because implementing both IPostBAckDataHandler and IPostBackEventHandler (Button does)
        'needs to call this so that postback event will be raised normally
        If Not postCollection(Me.UniqueID) Is Nothing Then
            Page.RegisterRequiresRaiseEvent(Me)
        End If
        Return False
    End Function

    Public Sub RaisePostDataChangedEvent() Implements System.Web.UI.IPostBackDataHandler.RaisePostDataChangedEvent
        'Not in use, but gotta implement because of the interface
    End Sub
End Class

---

Thanks,

Teemu Keiski
Finland, EU

I can't thank you enough!

---

Dimitris Papadimitriou

Hi again!

I have been trying to use your code with a LinkButton and an ImageButton as well. With a small modification I made it to work with ImageButton. I had to remove the Implements statement and override the LoadPostData that the ImageButton provides. LinkButton does not provide this method, so I suppose that your code should work as it is, as with the Button control. However, it does not (if I set a breakpoint I see that LoadPostData is not handled)! Do you know why?

---

Dimitris Papadimitriou

Yes, ImageButton is similar as it posts normally within Request.Form (just appending .x and .y there)

LinkButton posts itself differently (it uses __doPostBack call) e.g using javascript, it just implements IPostBackEventHandler. LinkButton posts itself so that it's UniqueID resides in __EVENTTARGET field in Request.Form collection (it's the hidden filed which resides with server-side form).

I have a blog post covering the checking of postbacking control in Page_Load, there's sample ( also LinkButton)
http://blogs.aspadvice.com/joteke/archive/2004/08/05/1444.aspx

E.g the relevant line is 
(Not Request.Form("__EVENTTARGET") Is Nothing AndAlso Request.Form("__EVENTTARGET").Equals(uniqueID))

---

Thanks,

Teemu Keiski
Finland, EU

well... now you gave me the idea to get the value of the hidden field without the implementation, using the Request.Form. And it works for all three controls. So why use the interface?
Thanks for helping me out.

---

Dimitris Papadimitriou

Because it still provides the way to work in standardized way with other part of the Page framework such as raising events about changes in posted data etc. And it brings the data available before Load event (with declaratively added controls or ones added in OnInit) when you don't need to deal with the page/control lifecycle (like if you now load data in OnLoad method and would want to access some of it on Page's Load, you might run into problems) Anyways, for simple state-keeping scenario it might not be needed, but is considerable when you need more features

The example where postback event was raised based on checking from post collection is quite "classic" control development sample, that it demonstrates how you need to work when your control deals with both postbacking interfaces (IPostBackEventHandler and IPostBackDataHandler) because only other one of them is handled automatically in scenario like that.

---

Thanks,

Teemu Keiski
Finland, EU